View source for NavigazioneMarittima:PowerBI Programmazione

=Custom visuals=
L'ambiente di sviluppo include l'installazione di '''node.js''', '''pbiviz''' e '''Visual Studio Code''' ([https://learn.microsoft.com/en-us/power-bi/developer/visuals/environment-setup preparazione ambiente di sviluppo]).
* Doc ufficiale: [https://learn.microsoft.com/en-us/power-bi/developer/visuals/power-bi-custom-visuals Cosa sono i CUSTOM VISUALS e dove si posson ottenere]
* Doc ufficiale: [https://learn.microsoft.com/en-us/power-bi/developer/visuals/power-bi-custom-visuals#custom-visual-files Custom visuals]
* Doc ufficiale: [https://learn.microsoft.com/en-us/power-bi/developer/visuals/develop-circle-card Tutorial - creare custom visuals]

=Linguaggio delle formule=
==Power Query M==
PowerBI usa un linguaggio interno per le composizioni delle formule chiamato: ''Power Query M'': [https://docs.microsoft.com/it-it/powerquery-m/power-query-m-function-reference ]<br />
<br />
Seguono lo stesso esempio in due momenti. E' il risultato del "Query Editor" dopo aver aggiunto una colonna con l' "Advanced Editor". Si aggiunge una colonna con la differenza di date, traformata in giorni e con l'aggiunta di 1 (giorno). PURTROPPO però questi cambiamenti non son tollerati dalla "''Direct Query''" di ciò se ne ha notizia al salvataggio.<br />
Es. 1
<pre>
let
    Source = Sql.Database("SPXMIW2869", "RS_Plan_ProjectVCVI_Test"),
    dbo_v_Projects = Source{[Schema="dbo",Item="v_Projects"]}[Data],
    #"Added Custom" = Table.AddColumn(dbo_v_Projects, "Days", each [DateTo]-[DateFrom]),
    #"Inserted Days" = Table.AddColumn(#"Added Custom", "Days.1", each Duration.Days([Days]) + 1, Int64.Type),
    #"Removed Columns" = Table.RemoveColumns(#"Inserted Days",{"Days"}),
    #"Reordered Columns" = Table.ReorderColumns(#"Removed Columns",{"IDProject", "IDOwner", "FullName", "Description", "DateFrom", "DateTo", "Days.1", "ProgressPerc"})
in
    #"Reordered Columns"
</pre>
Es. 2. Stessa funzione di prima ma semplificata
<pre>
let
    Source = Sql.Database("SPXMIW2869", "RS_Plan_ProjectVCVI_Test"),
    dbo_v_Projects = Source{[Schema="dbo",Item="v_Projects"]}[Data],
    #"Added Custom" = Table.AddColumn(dbo_v_Projects, "Days", each Duration.Days([DateTo]-[DateFrom]) + 1)
in
    #"Added Custom"
</pre>
==DAX==
Dax, Data Analysis Expressions, è una libreria di funzioni e operatori che è possibile combinare per creare formule ed espressioni nei modelli di dati per Power BI (ed anche per Analysis Services e Power Pivot in Excel).<br />
Le formule DAX includono funzioni, operatori e valori per eseguire query e calcoli avanzati sui dati presenti in tabelle e colonne correlate nei modelli di dati tabulari.
<br />
Ottimi manuali Online:
* [https://dax.guide/ dax.guide]
* [https://learn.microsoft.com/it-it/dax/dax-overview learn.microsoft]
Tutorial:
* [https://docs.microsoft.com/it-it/power-bi/guided-learning/introductiontodax?tutorial-step=1 microsoft.com]

===Varie===
Riferimento a tabelle:<br />
<code>'Table Name'[ColumnName]</code> caso in cui nel nome della tabella ci siano spazi
<code>TableName[ColumnName]</code>    caso in cui nel nome della tabella NON ci siano spazi

===Funzioni===
====Sulle Date====
* Restituisce la '''data di oggi''': <code>NOW()</code> , <code>TODAY()</code>
* Per avere solo l''''orario''' di una data: <code>TimeValue()</code> , es.:   Time = TimeValue([Date])
* Restituisce una '''data personalizzata''': <code>DATE()</code>, es.:  DATE( YEAR(TODAY()) + 1, 3, 31)
* Differenza in giorni tra due date: <code>DATEDIFF(<DataInizio>, <DataFine>, <intervallo>)</code>
  <intervallo> può essere: SECOND, MINUTE, HOUR, DAY, WEEK, MONTH, QUATER, YEAR
  è RESTITUITO SEMPRE UN VALORE INTERO
'''NOTA''' la '''data vuota''' è data da: DATE(00, 01, 01) che corrisponde al 01/01/1900

====Sulle Stringhe====
=====Canonici=====
* LEN(campo), restituisce la lunghezza di una stringa
* LEFT(campo, n), Prende i primi n caratteri di un campo stringa
* RIGHT(campo, n), Prende i primi n caratteri di un campo stringa
=====Varie soluzioni=====
* Substring() si simula così, ad es.: <code>_ada_format = LEFT(_SpecialDates[ada], 3) & "-" & LEFT(RIGHT(_SpecialDates[ada], LEN(_SpecialDates[ada]) - 3), 12)</code>

====Booleane - logiche====
Per verificare se il valore di un campo è nulla, NULL, si può usare <code>ISBLANK()</code>, quindi si potrà in aggiunta usare la funzione IF() che si paserà sul risultato della prima.<br />
NOTA la funzione <code>BLANK()</code> può esser usata per restituire un valore vuoto.
<pre>
[campoCalcolato] = IF(ISBLANK([Valore A])
                          ,BLANK()
                          ,DIVIDE(
                                 COUNTA(FILTER(Tabella, [Valore A] = "Yes"))
                                 ,COUNTA([Value A])
                                 )
                      )
</pre>

===Operatori logici===
<code>OR</code> = '''||'''    <code>AND</code> = '''&&'''
Esempio in una "Measure":
<pre>
Conditional Date1 = IF(([Selected DateFrom] <= [DatetoM1] 
							&& [Selected DateTo] >= [DateFromM1])
						|| [FlatStatus] = "Freezed" 
						|| [FlatStatus] = "Late" 
					 ,"T", "F") 
</pre>
====IF====
Doc [https://learn.microsoft.com/it-it/dax/if-function-dax IF]

<pre>IF(<logical_test>, <value_if_true>[, <value_if_false>])
</pre>
Parametri:

<div class="has-inner-focus">
{| class="table table-sm margin-top-none"
|-
!|Termine
!|Definizione
|-
||logical_test
||Qualsiasi valore o espressione che può dare come risultato TRUE o FALSE.
|-
||value_if_true
||Valore restituito se il test logico dà come risultato TRUE.
|-
||value_if_false
||(Facoltativo) Valore restituito se il test logico dà come risultato FALSE. Se omesso, viene restituito BLANK.
|}</div>
Es. nella definizione di una variabile:
<pre>
_parameter = IF(V_D_rpt_trf_cps_cc_rtype[rtype]="1" 
&& V_D_rpt_trf_cps_cc_rtype[site]="Rome"
				,CONCATENATE(" ", V_D_rpt_trf_cps_cc_rtype[parameter])
				,V_D_rpt_trf_cps_cc_rtype[parameter])
</pre>

====SWITCH====
E' simile al "CASE WHEN THEN ELSE" di T-SQL. Sintassi:
<pre>SWITCH(, , [, , ]…[, ])  
</pre>
Parametri

<div class="has-inner-focus">
{| class="table table-sm margin-top-none"
|-
!|Termine
!|Definizione
|-
||expression
||Qualsiasi espressione DAX che restituisce un singolo valore scalare, dove l'espressione deve essere valutata più volte (per ogni riga/contesto).
|-
||value
||Valore costante da confrontare con i risultati di expression.
|-
||result
||Qualsiasi espressione scalare da valutare se i risultati di expression corrispondono all'elemento value corrispondente.
|-
||else
||Qualsiasi espressione scalare da valutare se i risultati di expression non corrispondono a nessuno degli argomenti di value.
|}</div>
<div class="heading-wrapper" data-heading-level="h2"></div>
es.:

<pre>= SWITCH (
         [Month Number Of Year],
         1, "January",
         2, "February",
         3, "March",
         4, "April",
         5, "May",
         6, "June",
         7, "July",
         8, "August",
         9, "September",
         10, "October",
         11, "November",
         12, "December",
         "Unknown month number"
        )
= SWITCH (
        TRUE,
        [Reorder Point] > [Safety Stock Level], "Good: Safety stock level exceeded",
        [Reorder Point] = [Safety Stock Level], "Minimal: Safety stock level met",
        [Reorder Point] < [Safety Stock Level], "At risk: Safety stock level not met",
        ISBLANK ( [Reorder Point] ), "Incomplete: Reorder point not set",
        ISBLANK ( [Safety Stock Level] ), "Incomplete: Safety stock level not set",
        "Unknown"
        )
</pre>

===Elaborazioni dinamiche===
====CALCULATE====
* <code>CALCULATE(<expression>,<filter1>,<filter2>…)</code> Valuta una espressione nel contesto di dati filtrati. Il primo parametro, l'espressione, è essenzialmente una 'measure'. Il valore restituito è il risultato dell'espressione fornita [https://docs.microsoft.com/en-us/dax/calculate-function-dax Dettagli]

Es.:
<pre>
Selected DateFrom = CALCULATE (IF(FORMAT(MIN(Calendar[Date]), "dd/MM/yyyy") = FORMAT(TODAY(), "dd/MM/yyyy")
				, MIN(Calendar[Date])-20
				, MIN(Calendar[Date]))
				, ALLSELECTED(Calendar[Date]) )
</pre>
====Filtraggio====
* <code>ALL( [<table> | <column>[, <column>[, <column>[,…]]]] )</code>, il primo parametro è la tabella da cui rimuovere i filtri ed il secondo è la colonna. '''SCOPO:''' Restituisce una tabella o una colonna senza i filtri. [https://docs.microsoft.com/en-us/dax/all-function-dax Dettagli]
* <code>ALLSELECTED([<tableName> | <columnName>[, <columnName>[, <columnName>[,…]]]] )</code>, il primo parametro (opzionale) è il nome di una tabella esistente, il secondo parametro (opzionale) è il nome del campo della  tabella di prima. '''SCOPO:''' Restituisce il contesto della query CON i filtri. [https://docs.microsoft.com/en-us/dax/allselected-function-dax Dettagli]
* ISFILTERED(tabella[campo], valore se campo filtrato, valore se campo NON filtrato)
====Casi esemplari====
Uso ISFILTERED()<br />
Supponendo di verificare se uno slicer a selezione multipla sia filtrato:
[[File:SlicerPowerBI_CheckBox.png|none|100x77px]]
Si può creare una measure da visualizzare in una Card:
<pre>
_IsOwnerFiltered = IF ( ISFILTERED(v_ProjectOwners[OwnerName]), 1, 0)
</pre>
'''NOTA''' l'uso di due valori '1' e '0' nei casi di condizione positiva e negativa, le costanti true e false non sono gestibili.<br />
'''TIPS''', questo metodo potrebbe essere usato per "accendere" o "spegnere" altri visuals in funzione della scelta fatta sullo slicer, basta usare la mesaure appena creata come fitro nella rappresentazione delle grandezze nel visual che si vorrà accendere o spegnere.<br />

'''PROBLEMA''', <code>ISFILTERED()</code> è inefficace se inserito in una measure da valutare come campo ogni volta che viene selezionato un elemento dello slicer, occorre usare <code>SWITCH()</code>.<br />
Nel caso dobbiamo verificare un filtro che condizioni un calcolo in una measure di una vista converrrebbe usare <code>SWITCH()</code>.<br />
Con questa istruzione non possiamo riferirci a campi della vista che non siano oggetto di una funzione di aggregazione (es. MIN, MAX, SUM), pertanto occorre capire come i dati sono aggregati nel visual su cui rappresentare il campo calcolato.<br />
Nel seguente esempio la selezione di un owner deve influenzare il calcolo dei giorni di effort associati ad ogni Sistema il cui progetto dell'owner (Technical Leader) appartiene. Se non c'è selezione si divide l'effort per il numero di Sistemi\Vendor coinvolti, invece, se si seleziona un owner\technical leader l'effort va anche diviso per il numero di owner eventualmente associati al progetto.<br />
Si aggiungono due colonne con un calcolo in parallelo:
<pre>
_EffortFlatVendors = (v_ProjectOwners_Smpl[Effort] 
		/ v_ProjectOwners_Smpl[NrVendors])

_EffortFlatVendorsOwners = (v_ProjectOwners_Smpl[Effort] 
			    / v_ProjectOwners_Smpl[NrVendors]) 
			* 
			   (1
			    / v_ProjectOwners_Smpl[NrOwners])
</pre>
Quindi saranno usate nella measure che userà la SWITCH:
<pre>
_CalcSharedEffor = SWITCH(  SELECTEDVALUE( v_ProjectOwners_Smpl[OwnerName] )
			, "Owner1", SUM(v_ProjectOwners_Smpl[_EffortFlatVendors])
			, "Owne2", SUM(v_ProjectOwners_Smpl[_EffortFlatVendors])
			, "Owner3", SUM(v_ProjectOwners_Smpl[_EffortFlatVendors])
			, SUM(v_ProjectOwners_Smpl[_EffortFlatVendorsOwners])
			)
</pre>

===Variabili===
====Stringhe====
Elenco funzioni sulle stringhe: [https://docs.microsoft.com/it-it/dax/text-functions-dax docs.microsoft.com]<br />
'''COMBINEVALUES''', concatena con separatore n-campi di tabelle.<br />
<code>EVALUATE DISTINCT(SELECTCOLUMNS(DimDate, "Month", COMBINEVALUES(",", [MonthName], [CalendarYear])))</code><br />
Visualizzerà una tabella con la seguente colonna:
<pre>
January,2007
February,2007
...etc
</pre>

'''CONCATENATE''', Unisce due stringhe di testo in una sola.<br />
<code>CONCATENATE(<text1>, <text2>) </code><br />

'''RIGHT''', prende n caratteri di una stringa contando da destra<br />
<code>RIGHT(<text>, <num_chars>)</code><br />
Esempio:<br />
CONCATENATE("W", RIGHT(CONCATENATE("0", WEEKNUM('Calendar'[Date])), 2))<br />
Produrrà stringhe come: W01, W10, W54

====Date====
* DATE
* HOUR
* NOW()     restituisce la data di oggi ma CON orario
* TODAY()   restituisce la data di oggi ma SENZA orario
* EOMONTH
* WEEKDAY

====Funzione====
Calendar è una tabella col campo [Date]
<pre>
IsToday = 
	var currentRowDate = FORMAT(Calendar[Date], "dd/MM/yyyy")  
	
	var isToday= FORMAT(NOW(), "dd/MM/yyyy") 
	
	return 
		IF(isToday= currentRowDate
			, "yes"
			, "no")
</pre>

===Campi custom===
====Campo data senza orario====
Esiste già il campo <code>[adetdate]</code> nella vista <code>V_D_rpt_trf_cps_cc</code> ma è di tipo DateTime, senza appesantire la vista SQL si può aggiingere un "campo trasformato" in PowerBI, allo scopo la definizione del nuovo campo si può fare usando DAX. Segue esempio ma attenzione a cambiarne la tipologia di formato da testo a data.
<pre>
_adetdate_short = FORMAT('V_D_rpt_trf_cps_cc'[adetdate], "dd/MM/YY")
</pre>

====Campo ora da data====
Si usa la funzione <code>HOUR(<datetime>)</code>
<pre>
_hour = HOUR('V_D_rpt_trf_cps_cc'[adetdate])
</pre>

=Mappa e Link=
----
[[MSPowerApp:PowerBI | PowerBI]] | [[MS Power apps]]
----
[[MS SQL | MS SQL]] | [[MSSQL:SSRS | SSRS - Reporting Server]] | [[MSSQL:SSIS | SQL Integration Services]] | [[SWUtility:Reportistica | Tools di Reportistica]]<br />
[[C Sharp | C#]] | [[Visual Studio]] | [[Dizionario:Termini_tecnici_informatici | Dizionario IT]] 
----
'''Parole chiave''':